1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345 | * Тема: Гетероскедастично-состоятельные стандартные ошибки в форме Уайта (White's Heteroscedasticity-Consistent Standard Errors) для крупных, средних и малых выборок.
* Ключевые слова: гомоскедастичность, гетероскедастичность, регрессия, Уайт, White's, стандартные ошибки, Heteroscedasticity-Consistent Standard Errors, REGRESSION, MATRIX, регрессор, предиктор.
* Опубликован: 2002 г., перевод: 02.11.2008.
* Автор: Gwilym Pryce.
* Перевод: А. Балабанов.
* Размещение: http://www.spsstools.ru/Syntax/RegressionRepeatedMeasure/WhiteSE_HCO_HC2andHC3.txt (.sps).
* Проверено: SPSS 13.0.
*(i) HC0: Оригинальная процедура Уайта (White, 1980), применимая, когда есть крупная выборка (n > 500).
* Шаг №1: откройте ваш файл данных и сохраните его с другим именем, т.к. данная процедура перезапишет его с изменениями.
* Шаг №2: выполните МНК-регрессию и сохраните нестандартизированные (UNSTANDARDISED) остатки как RES_1:.
REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF OUTS R ANOVA
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT mp_pc
/METHOD=ENTER xp_pc gdp_pc
/SAVE RESID(RES_1) .
* Шаг №3: создайте переменную ESQ = квадрат остатков:.
COMPUTE ESQ = RES_1 * RES_1.
EXECUTE.
* Шаг №4: создайте переменную CONSTANT: постоянное значение = 1 для всех наблюдений в выборке.
FILTER OFF.
USE ALL.
EXECUTE .
COMPUTE CONSTANT = 1.
EXECUTE.
* Шаг №5: отфильтруйте наблюдения с пропущенными значениями.
FILTER OFF.
USE ALL.
SELECT IF(MISSING(ESQ) = 0).
EXECUTE .
* Шаг №6: войдите в режиме синтаксиса в программу матричных вычислений SPSS.
* Вам потребуется ввести имена Y и X-переменных из вашей регрессии.
* После этого процедура вычислит стандартные ошибки в форме Уайта для крупной выборки.
*** Примеч.: в программе ниже вам нужно изменить только имена переменных во 2 и 3-й строках так, чтобы
они совпадали с именами из вашего регрессионного анализа.
MATRIX.
GET Y / VARIABLES = mp_pc.
GET X / VARIABLES = CONSTANT, xp_pc, gdp_pc
/ NAMES = XTITLES.
GET RESIDUAL / VARIABLES = RES_1.
GET ESQ / VARIABLES = ESQ.
COMPUTE XRTITLES = TRANSPOS(XTITLES).
COMPUTE N = NROW(ESQ).
COMPUTE K = NCOL(X).
COMPUTE O = MDIAG(ESQ).
COMPUTE WHITEV = (INV(TRANSPOS(X) * X)) *TRANSPOS(X)* O * X*INV(TRANSPOS(X) * X).
COMPUTE WDIAG = DIAG(WHITEV).
COMPUTE WHITE_SE = SQRT(WDIAG).
PRINT WHITE_SE
/ FORMAT = "E13"
/ TITLE = "Состоятельные стандартные ошибки в форме Уайта (для крупной выборки)"
/ RNAMES = XRTITLES.
COMPUTE B = (INV(TRANSPOS(X) * X)) * (TRANSPOS(X) * Y).
PRINT B
/ FORMAT = "E13"
/TITLE = "Коэффициенты МНК"
/ RNAMES = XRTITLES.
COMPUTE WT_VAL = B / WHITE_SE.
PRINT WT_VAL
/ FORMAT = "E13"
/ TITLE = "t-статистики на основе СО в форме Уайта (крупная выборка)"
/ RNAMES = XRTITLES.
COMPUTE SIG_WT = 2*(1- TCDF(ABS(WT_VAL), N)) .
PRINT SIG_WT
/ FORMAT = "E13"
/ TITLE = "Собств. уровень значимости (Prob(t < tc)) t-статистики на основе СО в форме Уайта (крупная выборка)"
/ RNAMES = XRTITLES.
COMPUTE SIGMASQ = (TRANSPOS(RESIDUAL)*RESIDUAL)/(N-K).
COMPUTE SE_SQ = SIGMASQ*INV(TRANSPOS(X)*X).
COMPUTE SESQ_ABS = ABS(SE_SQ).
COMPUTE SE = SQRT(DIAG(SESQ_ABS)).
PRINT SE
/ FORMAT = "E13"
/ TITLE = "Стандартные ошибки МНК"
/ RNAMES = XRTITLES.
COMPUTE OLST_VAL = B / SE.
PRINT OLST_VAL
/ FORMAT = "E13"
/ TITLE = "t-статистики на основе СО МНК"
/ RNAMES = XRTITLES.
COMPUTE SIG_OLST = 2*(1- TCDF(ABS(OLST_VAL), N)) .
PRINT SIG_OLST
/ FORMAT = "E13"
/ TITLE = "Собств. уровень значимости (Prob(t < tc)) t-статистики на основе СО МНК"
/ RNAMES = XRTITLES.
COMPUTE WESTIM = {B, SE, WHITE_SE, WT_VAL, SIG_WT}.
PRINT WESTIM
/ FORMAT = "E13"
/ RNAMES = XRTITLES
/ CLABELS = B, SE, WHITE_SE, WT_VAL, SIG_WT.
END MATRIX.
* Примечания:
* Не сохраняйте полученный файл под тем же именем, т.к. процедура изменяет исходный файл (удаляет наблюдения с пропущенными значениями).
* Если в вашем файле уже есть переменная с именем res_1, вам нужно будет удалить или переименовать её перед запуском синтаксиса. Это
также означает, что если вы будете запускать синтаксис для разных уравнений регрессии (разных моделей), всякий раз перед запуском
вам потребуется удалять старые переменные res_1 и ESQ.
* Результаты выводятся в "научном" формате, т.е., например, 20.7 будет записано как 2.07E+01, 0.00043 - как 4.3E-04.
* Последняя таблица выдачи просто объединяет в одном месте информацию из пяти предыдущих таблиц.
* WT_VAL - аббревиатура для "White's t-values" (t-статистики на основе ... Уайта), а SIG_WT - аббревиатура для
"significance level ... t values" (собственный уровень значимости для t-статистики на основе ...Уайта).
* Пример вычисления стандартных ошибок в форме Уайта (пример результата работы приведённой выше программы).
* Если мы запустим указанный выше синтаксис на примере из моей статьи, связанном с прогнозом общей площади на основе
возраста здания, числа спален и ванных комнат, мы получим:
* (см. http://www.spsstools.net/Tutorials/HeteroscedasticityTestingAndCorrectingInSPSS.zip - примеч. перев.).
* Результат работы процедуры MATRIX:
*Состоятельные стандартные ошибки в форме Уайта (для крупной выборки)
*CONSTANT 4.043030E-02
*AGE_DWEL 1.715285E-04
*BATHROOM 2.735781E-02
*BEDROOMS 1.284207E-02
*Коэффициенты МНК
*CONSTANT 3.536550E+00
*AGE_DWEL 1.584464E-03
*BATHROOM 2.258710E-01
*BEDROOMS 2.721069E-01
*t-статистики на основе СО в форме Уайта (крупная выборка)
*CONSTANT 8.747276E+01
*AGE_DWEL 9.237322E+00
*BATHROOM 8.256180E+00
*BEDROOMS 2.118870E+01
*Собств. уровень значимости (Prob(t < tc)) t-статистики на основе СО в форме Уайта (крупная выборка)
*CONSTANT 0.000000E+00
*AGE_DWEL 0.000000E+00
*BATHROOM 2.220446E-16
*BEDROOMS 0.000000E+00
*Стандартные ошибки МНК
*CONSTANT 3.514394E-02
*AGE_DWEL 1.640008E-04
*BATHROOM 2.500197E-02
*BEDROOMS 1.155493E-02
*t-статистики на основе СО МНК
*CONSTANT 1.006304E+02
*AGE_DWEL 9.661319E+00
*BATHROOM 9.034130E+00
*BEDROOMS 2.354899E+01
*Собств. уровень значимости (Prob(t < tc)) t-статистики на основе СО МНК
*CONSTANT 0.000000E+00
*AGE_DWEL 0.000000E+00
*BATHROOM 0.000000E+00
*BEDROOMS 0.000000E+00
*WESTIM
* B SE WHITE_SE WT_VAL SIG_WT
*CONSTANT 3.536550E+00 3.514394E-02 4.043030E-02 8.747276E+01 0.000000E+00
*AGE_DWEL 1.584464E-03 1.640008E-04 1.715285E-04 9.237322E+00 0.000000E+00
*BATHROOM 2.258710E-01 2.500197E-02 2.735781E-02 8.256180E+00 2.220446E-16
*BEDROOMS 2.721069E-01 1.155493E-02 1.284207E-02 2.118870E+01 0.000000E+00
*(ii) HC2 и HC3: Процедура MATRIX для расчёта состоятельных стандартных ошибок, если объём выборки < 500 :.
* В случае малых по объёму выборок стандартные ошибки в форме Уайта оказываются ненадежными.
* MacKinnon и White (1985) предложили 3 проверки для случая малых выборок.
* Long и Ervin (1999) установили, что третья из этих проверок (называемая HC3) является наиболее надежной.
* Но, в зависимости от объёма оперативной памяти вашего компьютера, вы можете обнаружить сложности с вычислением HC3 в
случаях, когда объём выборки превышает 250 наблюдений.
* Принимая все это во внимание, я бы рекомендовал следующее:.
*n < 250 - используем HC3 вне зависимости от того, оказалась ли проверка на гетероскедастичность положительной
(Long и Ervin показали, что эти проверки не имеют достаточной мощности на малых выборках).
*250 < n < 500 - используем HC2, т.к. этот вариант более надёжен, чем HC0 (HC0 = оригинальная процедура Уайта для расчёта
состоятельных стандартных ошибок, приведённая выше).
*n > 500 - используем либо HC2, либо HC0.
*** Для современных компьютеров, вероятно, порог в 250 наблюдений может быть существенно увеличен - примеч. перев.
*Синтаксис для вычисления HC2 приведён ниже. Первые 5 шагов вы выполняете тем же манером, что и для HC0, а затем запускаете следующее:
*HC2.
MATRIX.
GET Y / VARIABLES = flarea_l.
GET X / VARIABLES = CONSTANT, age_dwel, bathroom, bedrooms
/ NAMES = XTITLES.
GET RESIDUAL / VARIABLES = RES_1.
GET ESQ / VARIABLES = ESQ.
COMPUTE XRTITLES = TRANSPOS(XTITLES).
COMPUTE N = NROW(ESQ).
COMPUTE K = NCOL(X).
COMPUTE O = MDIAG(ESQ).
/*Вычисление HC2*/.
COMPUTE XX = TRANSPOS(X) * X.
COMPUTE XX_1 = INV(XX).
COMPUTE X_1 = TRANSPOS(X).
COMPUTE H = X*XX_1*X_1.
COMPUTE H_MONE = h * -1.
COMPUTE ONE_H = H_MONE + 1.
COMPUTE O_HC2 = O &/ ONE_H.
COMPUTE HC2_a = XX_1 * X_1 *O_HC2.
COMPUTE HC2 = HC2_a * X*XX_1.
COMPUTE HC2DIAG = DIAG(HC2).
COMPUTE HC2_SE = SQRT(HC2DIAG).
PRINT HC2_SE
/ FORMAT = "E13"
/ TITLE = "HC2 - состоятельные стандартные ошибки для малых выборок"
/ RNAMES = XRTITLES.
COMPUTE B = XX_1 * X_1 * Y.
PRINT B
/ FORMAT = "E13"
/TITLE = "Коэффициенты МНК"
/ RNAMES = XRTITLES.
COMPUTE HC2_TVAL = B / HC2_SE.
PRINT HC2_TVAL
/ FORMAT = "E13"
/ TITLE = "t-статистики на основе HC2-состоятельных стандартных ошибок"
/ RNAMES = XRTITLES.
COMPUTE SIG_HC2T = 2*(1- TCDF(ABS(HC2_TVAL), N)) .
PRINT SIG_HC2T
/ FORMAT = "E13"
/ TITLE = "Собств. уровень значимости (Prob(t < tc)) для t-статистик на основе HC2 СО"
/ RNAMES = XRTITLES.
END MATRIX.
*Пример результата работы приведённого выше синтаксиса:.
*HC2 - состоятельные стандартные ошибки для малых выборок.
*CONSTANT 4.077517E-02.
*AGE_DWEL 1.726199E-04.
*BATHROOM 2.761153E-02.
*BEDROOMS 1.293651E-02.
*Коэффициенты МНК.
*CONSTANT 3.536550E+00.
*AGE_DWEL 1.584464E-03.
*BATHROOM 2.258710E-01.
*BEDROOMS 2.721069E-01.
*t-статистики на основе HC2-состоятельных стандартных ошибок.
*CONSTANT 8.673291E+01.
*AGE_DWEL 9.178915E+00.
*BATHROOM 8.180314E+00.
*BEDROOMS 2.103402E+01.
*Собств. уровень значимости (Prob(t < tc)) для t-статистик на основе HC2 СО.
*CONSTANT 0.000000E+00.
*AGE_DWEL 0.000000E+00.
*BATHROOM 1.998401E-15.
*BEDROOMS 0.000000E+00.
*Перед запуском HC3 убедитесь, что ваша выборка не слишком велика, иначе возникнет какое-нибудь переполнение памяти компьютера.
*Как вариант, можно временно выделить из ваших данных случайную подвыборку во время действия команды TEMPORARY:.
*SAMPLE p., где p - доля наблюдений, попадающих в выборку (т.е., если p = 0.4, вы выберите около 40% наблюдений из вашей выборки для следующей процедуры).
*HC3.
/*перед запуском убедитесь, что n < 250 */.
TEMPORARY.
SAMPLE 0.4.
MATRIX.
GET Y / VARIABLES = flarea_l.
GET X / VARIABLES = CONSTANT, age_dwel, bathroom, bedrooms
/ NAMES = XTITLES.
GET RESIDUAL / VARIABLES = RES_1.
GET ESQ / VARIABLES = ESQ.
COMPUTE XRTITLES = TRANSPOS(XTITLES).
COMPUTE N = NROW(ESQ).
COMPUTE K = NCOL(X).
COMPUTE O = MDIAG(ESQ).
COMPUTE XX = TRANSPOS(X) * X.
COMPUTE XX_1 = INV(XX).
COMPUTE X_1 = TRANSPOS(X).
COMPUTE H = X*XX_1*X_1.
COMPUTE H_MONE = h * -1.
COMPUTE ONE_H = H_MONE + 1.
/*Вычисление HC3*/.
COMPUTE ONE_H_SQ = ONE_H &** 2.
COMPUTE O_HC3 = O &/ ONE_H_SQ.
COMPUTE HC3_a = XX_1 * X_1 *O_HC3.
COMPUTE HC3 = HC3_a * X*XX_1.
COMPUTE HC3DIAG = DIAG(HC3).
COMPUTE HC3_SE = SQRT(HC3DIAG).
COMPUTE B = XX_1 * X_1 * Y.
PRINT B
/ FORMAT = "E13"
/TITLE = "Коэффициенты МНК".
PRINT HC3_SE
/ FORMAT = "E13"
/ TITLE = "HC3 - состоятельные стандартные ошибки для малых выборок"
/ RNAMES = XRTITLES.
COMPUTE HC3_TVAL = B / HC3_SE.
PRINT HC3_TVAL
/ FORMAT = "E13"
/ TITLE = "t-статистики на основе HC3-состоятельных СО"
/ RNAMES = XRTITLES.
COMPUTE SIG_HC3T = 2*(1- TCDF(ABS(HC3_TVAL), N)) .
PRINT SIG_HC3T
/ FORMAT = "E13"
/ TITLE = "Собств. уровень значимости (Prob(t < tc)) для t-статистики на основе HC3 СО"
/ RNAMES = XRTITLES.
END MATRIX.
*Пример результата работы приведённого выше синтаксиса:.
*Коэффициенты МНК.
* 3.530325E+00.
* 1.546620E-03.
* 2.213146E-01.
* 2.745376E-01.
*HC3 - состоятельные стандартные ошибки для малых выборок.
*CONSTANT 4.518059E-02.
*AGE_DWEL 1.884062E-04.
*BATHROOM 3.106637E-02.
*BEDROOMS 1.489705E-02.
*t-статистики на основе HC3-состоятельных СО.
*CONSTANT 7.813809E+01.
*AGE_DWEL 8.208966E+00.
*BATHROOM 7.123928E+00.
*BEDROOMS 1.842899E+01.
*Собств. уровень значимости (Prob(t < tc)) для t-статистики на основе HC3 СО.
*CONSTANT 0.000000E+00.
*AGE_DWEL 2.220446E-15.
*BATHROOM 4.005019E-12.
*BEDROOMS 0.000000E+00.
*Литература:.
*H. White. 1980. "A Heteroskedasticity-Consistent Covariance Matrix and a Direct Test for Heteroskedasticity." Econometrica, 48, 817-838.
*MacKinnon, J.G. and H. White. (1985), 'Some heteroskedasticity consistent covariance matrix estimators with improved finite sample properties'. Journal of Econometrics, 29, 53-57.
*Long, J. S. and Laurie H. Ervin (1999) "Using Heteroscedasticity Consistent Standard Errors in the Linear Regression Model", Mimeo, Indiana University. http://www.indiana.edu/~jsl650/files/hccm/99TAS.pdf.
|