Регрессия с k «проверочными» (hold-out) наблюдениями

* (ВОПРОС) Есть ли какой-то синтаксис, который позволяет строить регрессионные уравнения,
	оставляя при этом заданное число "проверочных" (hold-out) наблюдений? Я знаю, что 
	сохранение исправленных (adjusted) прогнозов даёт прогнозы для каждого отдельного
	наблюдения при исключении его из расчёта коэффициентов, но хотелось бы использовать
	в качестве проверочных не одно, а, скажем, 5 наблюдений для получения лучшего 
	впечатления о точности регрессионной модели...
* (ОТВЕТ) Автор: rlevesque@videotron.ca, 01.09.2001.
*	http://www.spsstools.net.


SET MPRINT=no.
*///////////////////////////.
DEFINE !regres( use=!TOKENS(1) 
	/nbcases=!TOKENS(1) 
	/dep=!TOKENS(1)
	/indep=!CMDEND)

COMPUTE caseid=$CASENUM.
/* Подсчитаем число вариантов регрессионных уравнений как разность между nbcases и use*/
!LET !nbloop=!LEN(!SUBSTR(!BLANK(!nbcases),!use))

!DO !casebeg=1 !TO !nbloop
/* вычислим номер последнего наблюдения, которое используется на данном шаге для расчёта коэффициентов */.
!LET !caseend = !LEN(!SUBSTR(!CONCAT( !BLANK(!casebeg),!BLANK(!use)),2))

/* вычисляем фильтрующую переменную */.
COMPUTE !CONCAT('svar',!casebeg)=0.
IF RANGE(caseid ,!casebeg, !caseend ) !CONCAT('svar',!casebeg)=1.

REGRESSION
  /SELECT= !CONCAT('svar',!casebeg) EQ 1
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT !dep
  /METHOD=ENTER !indep
  /SAVE PRED.
!DOEND

!ENDDEFINE.
*///////////////////////////.

SET MPRINT=yes.

****** Пример 1.
GET
  FILE='c:\\Program Files\\SPSS\\Employee data.sav'.
N OF CASES 20.
* Допустим, хотим использовать 15 наблюдений для анализа (5 проверочных наблюдений).
!regres use=15 nbcases=20 dep=salary indep=educ jobtime.

****** Пример 2.
GET
  FILE='c:\\Program Files\\SPSS\\Employee data.sav'.
N OF CASES 22.
!regres use=16 nbcases=22 dep=salary indep=educ jobtime.