Выборочное распределение парного коэффициента корреляции

* Опубликован: 30.12.2005.
*(Вопрос) Я хотел бы осуществить 1000 выборок из двумерной совокупности и для каждой выборки подсчитать корреляцию между двумя переменными, а затем - вывести на график выборочное распределение коэффициентов.

* (Ответ) Размещён в SPSSX_L 16 ноября 2001 Jelani Mandara.

DEFINE !sdist (samples=!TOKENS(1) /size=!TOKENS(1) /mean=!TOKENS(1)
 /sd=!TOKENS(1)).

INPUT PROGRAM.
LOOP id = 1 TO !samples* !size.
END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.

RANK
  VARIABLES = id
  /NTILES(!size)
  /PRINT = NO
  /TIES = MEAN .

* Переменная nid появляется в результате предыдущего ранжирования.
SORT CASES BY nid .
SPLIT FILE
  LAYERED BY nid .

* Независимо симулируем нормально распределённые переменные с заданным средним и стандартом.
COMPUTE X = RV.NORMAL(!mean,!sd) .
COMPUTE Y = RV.NORMAL(!mean,!sd) .

DESCRIPTIVES
  VARIABLES=x y  /SAVE
  /STATISTICS=MEAN.

* Переменные zx и zy появляются в результате стандартизации, запрошенной в предыдущей команде DESCRIPTIVES.
COMPUTE ZxZy = zx * zy .
SPLIT FILE OFF.

AGGREGATE
  /OUTFILE='C:\\temp\\samplingdistribution.SAV'
  /BREAK=nid
  /zxzy = SUM(zxzy)
  /N_BREAK=N.

GET
  FILE='C:\\temp\\samplingdistribution.SAV'.

* Вычисляем коэффициент корреляции как сумму произведений стандартизированных переменных, полученную в предыдущей команде агрегирования, делённую на количество элементов в выборке.
COMPUTE corr = zxzy / n_break .
FREQUENCIES
  VARIABLES=corr  /FORMAT=NOTABLE
  /STATISTICS=STDDEV VARIANCE MINIMUM MAXIMUM SEMEAN MEAN MEDIAN
  /HISTOGRAM  NORMAL
  /ORDER  ANALYSIS .
!ENDDEFINE.

!sdist samples=100 size=100 mean =100 sd =15.