*(Вопрос) Требуется создать отдельный HTML-файл с таблицей для каждого уникального значения переменной Product.
*(Ответ) Размещено в SPSSX-L, автор: Raynald Levesque, 30.03.2004.
* Полностью автоматизированное решение.
DATA LIST LIST /Product (A1) RATING (F2.0) VPoor (PCT2.0) Poor (PCT2.0)
Neutral (PCT2.0) Good (PCT2.0) Excelnt (PCT2.0) Mean (F3.2) N (F5.0) OUTPUT
(A8).
BEGIN DATA
A 1 17 08 33 17 25 3.25 12 Report_A
A 2 17 08 33 17 25 3.25 12 Report_A
B 1 17 08 33 08 33 3.33 14 Report_B
B 2 42 08 08 08 33 2.83 14 Report_B
C 1 17 42 08 08 25 2.83 18 Report_C
C 2 17 17 33 08 25 3.08 18 Report_C
D 1 42 08 17 08 25 2.67 22 Report_D
D 2 17 00 17 42 25 3.58 22 Report_D
END DATA.
VAR LABELS Excelnt 'Отлично' Good 'Хорошо' Neutral 'Нейтрально' Poor 'Плохо' VPoor 'Ужасно' Mean 'Ср. балл' Rating 'Рейтинг'.
SAVE OUTFILE='c:\\temp\\original data.sav'.
SORT CASES BY product.
AGGREGATE OUTFILE=*
/PRESORTED
/BREAK=product
/notused=N.
WRITE OUTFILE='c:\\temp\\macro calls.sps'
/"!doit prod='"product"'.".
EXECUTE.
*///////////////.
DEFINE !doit (prod=!TOKENS(1))
SET MPRINT=yes.
TEMPORARY.
OMS /SELECT TEXTS
/IF COMMANDS = ['Report']
/DESTINATION FORMAT = HTML OUTFILE = !QUOTE(!CONCAT('C:\\TEMP\\REPORT_',!UNQUOTE(!prod),'.HTM')).
SELECT IF Product=!prod.
Report
/FORMAT= CHWRAP(ON) PREVIEW(OFF) CHALIGN(BOTTOM) UNDERSCORE(ON)
ONEBREAKCOLUMN(OFF) CHDSPACE(1) SUMSPACE(0) AUTOMATIC LIST BRKSPACE(-1)
PAGE(1) MISSING'.' LENGTH(1, 99999) ALIGN(LEFT) TSPACE(1) FTSPACE(1) MARGINS(1,79)
/TITLE= CENTER !QUOTE(!CONCAT('Продукт ',!UNQUOTE(!prod))) RIGHT 'Стр. )PAGE'
/VARIABLES
RATING (VALUES) (RIGHT) (OFFSET(0)) (8)
Mean (VALUES) (RIGHT) (OFFSET(0)) (8)
N (VALUES) (RIGHT) (OFFSET(0)) (8)
Excelnt (VALUES) (RIGHT) (OFFSET(0)) (9)
Good (VALUES) (RIGHT) (OFFSET(0)) (8)
Neutral (VALUES) (RIGHT) (OFFSET(0)) (8)
Poor (VALUES) (RIGHT) (OFFSET(0)) (8)
VPoor (VALUES) (RIGHT) (OFFSET(0)) (8) .
OMSEND.
SET MPRINT=no.
!ENDDEFINE.
*///////////////.
GET FILE='c:\\temp\\original data.sav'.
INCLUDE 'c:\\temp\\macro calls.sps'.