Скопировать метку переменной и метки её значений на другие переменные

* Как приписать метку переменной и метки её значений другим переменным.
* Это ИСКЛЮЧИТЕЛЬНО полезное решение.
* Автор:Raynald Levesque,rlevesque@videotron.ca, март 2001.

SET MPRINT=yes.

* Копируем метку переменной и метки её значений в несколько переменных.
*/////////////////////////////////.
DEFINE !applab (!POS=!TOKENS(1) /tovars=!CMDEND)

RENAME VARIABLES (!1=model).
!LET !filenam=!QUOTE(!CONCAT('c:\\temp\\dictionary',!1,'.sav'))
SAVE OUTFILE=!filenam /KEEP=model.
RENAME VARIABLES (model=!1).
!DO !var !IN (!tovars)
RENAME VARIABLES (!var=model).
APPLY DICTIONARY FROM !filenam.
RENAME VARIABLES (model=!var).
!DOEND
!ENDDEFINE.
*/////////////////////////////////.
 
GET FILE='c:\\program files\\spss\\employee data.sav'.

COMPUTE jobcat1=jobcat.
COMPUTE test=jobcat.
COMPUTE test2=jobcat.

* Следующий вызов макроса копирует метку переменной jobcat
* и метки её значений на переменные jobcat1 test and test2.
!applab jobcat tovars=jobcat1 test test2.
EXECUTE.